Ratio Estimation of Dead Fir Trees
A forest resource manager is interested in estimating the number
of dead fir trees in a 300-acre area of heavy infestation. Using
an aerial photo, he divides the area into 200 one-and-a-half-acre
plots. Let x denote the photo count of dead firs and y the actual
ground count for a simple random sample of n=10 plots. The total
number of dead fir trees obtained from the photo count is Tx=4200.
Estimate Ty, the total number of dead firs in the 300-acre area.
Source: Exercise 6.9. Page 159 of Scheaffer, R.L., W. Mendenhall,
and L. Ott. 1986. Elementary Survey Sampling, Third Edition.
Duxbury Press, Boston.
dm "output;clear;log;clear";
************************************************************;
* FirTrees.sas -- Use of ratio estimator to correct *;
* counts from an aerial photo with ground-truth data. *;
************************************************************;
ODS HTML body= "FirTrees-body.html"
headtext="<title>Ratio Estimation of Dead Fir Trees</title>"
anchor="firtrees";
Options PS=55 LS=80 PageNo=1 NoDate
FORMCHAR='|----|+|---+=|-/\<>*';
GOptions Device=gif Transparency NoBorder NoPrompt
VSize=6 in HSize=6 in
HText=1 FText=Swiss HTitle=1 FTitle=Swiss;
Title1 "Ratio Estimation For Fir Tree Counts";
/*
* Exercise 6.9. Page 159 of Scheaffer, R.L., W. Mendenhall,
* and L. Ott. 1986. Elementary Survey Sampling, Third Edition.
* Duxbury Press, Boston.
*
* A forest resource manager is interested in estimating the number
* of dead fir trees in a 300-acre area of heavy infestation. Using
* an aerial photo, he divides the area into 200 one-and-a-half-acre
* plots. Let x denote the photo count of dead firs and y the actual
* ground count for a simple random sample of n=10 plots. The total
* number of dead fir trees obtained from the photo count is Tx=4200.
* Estimate Ty, the total number of dead firs in the 300-acre area.
*/
Data DeadFirs;
Input Plot PhotoCount GroundCount;
RatioWeight=1/PhotoCount;
SamplingWeight=200/10;
DataLines;
1 12 18
2 30 42
3 24 24
4 24 36
5 18 24
6 30 36
7 12 14
8 6 10
9 36 48
10 42 54
;
Proc Print Data=DeadFirs;
Run;
/*
* Get a look at the relationship between ground and photo
* counts. See if variance is related to the photo counts
* and if line through the origin appears satisfactory.
*/
Proc GPlot Data=DeadFirs;
Plot GroundCount*PhotoCount=1 / VAxis=Axis1 HAxis=Axis2;
Axis1 Order=(0 To 60 By 10) Label=(A=90 "Ground Count") Length=5in;
Axis2 Order=(0 To 60 By 10) Label=("Photo Count") Length=5in;
Symbol1 C=Black V=Dot I=RL0 L=1;
Run;
Quit;
/*
* First, let's estimate the number of dead fir trees
* just using the ground count data. That is, as if we
* had not made use of the photo information.
*/
Title2 "Estimation Using Ground Counts Only";
Proc SurveyMeans Data=DeadFirs N=200
Mean CLM Sum CLSUM CV;
Var GroundCount;
Weight SamplingWeight;
Run;
/*
* Use the ratio estimator to correct the photo
* counts using the known ground-count data.
* The design-based estimator uses the usual ratio
* estimator found in most sampling texts. The
* model-based estimator is the more typical
* regression through the origin estimate.
*/
Title2 "Estimation Incorporating Photo Counts";
Title3 "Design-based Estimate";
Proc SurveyReg Data=DeadFirs N=200;
Model GroundCount = PhotoCount / NoInt Solution CLParm;
Estimate "Mean Ground Count" PhotoCount 4200 / Divisor=200;
Estimate "Total Ground Count" PhotoCount 4200;
Weight RatioWeight;
Run;
Title3 "Model-based Estimate";
Proc SurveyReg Data=DeadFirs N=200;
Model GroundCount = PhotoCount / NoInt Solution CLParm;
Estimate "Mean Ground Count" PhotoCount 4200 / Divisor=200;
Estimate "Total Ground Count" PhotoCount 4200;
Run;
ODS HTML Close;
| Ratio Estimation For Fir Tree Counts |
| Obs |
Plot |
PhotoCount |
GroundCount |
RatioWeight |
SamplingWeight |
| 1 |
1 |
12 |
18 |
0.08333 |
20 |
| 2 |
2 |
30 |
42 |
0.03333 |
20 |
| 3 |
3 |
24 |
24 |
0.04167 |
20 |
| 4 |
4 |
24 |
36 |
0.04167 |
20 |
| 5 |
5 |
18 |
24 |
0.05556 |
20 |
| 6 |
6 |
30 |
36 |
0.03333 |
20 |
| 7 |
7 |
12 |
14 |
0.08333 |
20 |
| 8 |
8 |
6 |
10 |
0.16667 |
20 |
| 9 |
9 |
36 |
48 |
0.02778 |
20 |
| 10 |
10 |
42 |
54 |
0.02381 |
20 |
| Ratio Estimation For Fir Tree Counts |
| Estimation Using Ground Counts Only |
| The SURVEYMEANS Procedure |
| Data Summary |
| Number of Observations |
10 |
| Sum of Weights |
200 |
| Statistics |
| Variable |
Mean |
Std Error of Mean |
Lower 95%
CL for Mean |
Upper 95%
CL for Mean |
Coeff of Variation |
Sum |
Std Dev |
Lower 95%
CL for Sum |
Upper 95%
CL for Sum |
| GroundCount |
30.600000 |
4.576729 |
20.246721 |
40.953279 |
0.149566 |
6120.000000 |
915.345715 |
4049.344135 |
8190.655865 |
| Ratio Estimation For Fir Tree Counts |
| Estimation Incorporating Photo Counts |
| Design-based Estimate |
| The SURVEYREG Procedure |
| Regression Analysis for Dependent Variable GroundCount |
| Data Summary |
| Number of Observations |
10 |
| Sum of Weights |
0.59048 |
| Weighted Mean of GroundCount |
22.66935 |
| Weighted Sum of GroundCount |
13.38571 |
| Fit Statistics |
| R-square |
0.9870 |
| Root MSE |
3.1505 |
| Denominator DF |
9 |
| ANOVA for Dependent Variable GroundCount |
| Source |
DF |
Sum of Squares |
Mean Square |
F Value |
Pr > F |
| Model |
1 |
400.1538 |
400.1538 |
682.76 |
<.0001 |
| Error |
9 |
5.2747 |
0.5861 |
|
|
| Uncorrected Total |
10 |
405.4286 |
|
|
|
| Tests of Model Effects |
| Effect |
Num DF |
F Value |
Pr > F |
| Model |
1 |
816.18 |
<.0001 |
| PhotoCount |
1 |
816.18 |
<.0001 |
| NOTE: |
The denominator degrees of freedom for the F tests is 9. |
|
| Estimated Regression Coefficients |
| Parameter |
Estimate |
Standard Error |
t Value |
Pr > |t| |
95% Confidence Interval |
| PhotoCount |
1.30769231 |
0.04577331 |
28.57 |
<.0001 |
1.20414590 |
1.41123872 |
| NOTE: |
The denominator degrees of freedom for the t tests is 9. |
|
| Analysis of Estimable Functions |
| Parameter |
Estimate |
Standard Error |
t Value |
Pr > |t| |
95% Confidence Interval |
| Mean Ground Count |
27.46154 |
0.961239 |
28.57 |
<.0001 |
25.28706 |
29.63601 |
| Total Ground Count |
5492.30769 |
192.247882 |
28.57 |
<.0001 |
5057.41277 |
5927.20262 |
| NOTE: |
The denominator degrees of freedom for the t tests is 9. |
|
| Ratio Estimation For Fir Tree Counts |
| Estimation Incorporating Photo Counts |
| Model-based Estimate |
| The SURVEYREG Procedure |
| Regression Analysis for Dependent Variable GroundCount |
| Data Summary |
| Number of Observations |
10 |
| Mean of GroundCount |
30.60000 |
| Sum of GroundCount |
306.00000 |
| Fit Statistics |
| R-square |
0.9905 |
| Root MSE |
3.4672 |
| Denominator DF |
9 |
| ANOVA for Dependent Variable GroundCount |
| Source |
DF |
Sum of Squares |
Mean Square |
F Value |
Pr > F |
| Model |
1 |
11239.81 |
11239.81 |
934.97 |
<.0001 |
| Error |
9 |
108.19 |
12.02 |
|
|
| Uncorrected Total |
10 |
11348.00 |
|
|
|
| Tests of Model Effects |
| Effect |
Num DF |
F Value |
Pr > F |
| Model |
1 |
1120.38 |
<.0001 |
| PhotoCount |
1 |
1120.38 |
<.0001 |
| NOTE: |
The denominator degrees of freedom for the F tests is 9. |
|
| Estimated Regression Coefficients |
| Parameter |
Estimate |
Standard Error |
t Value |
Pr > |t| |
95% Confidence Interval |
| PhotoCount |
1.29909910 |
0.03881147 |
33.47 |
<.0001 |
1.21130146 |
1.38689674 |
| NOTE: |
The denominator degrees of freedom for the t tests is 9. |
|
| Analysis of Estimable Functions |
| Parameter |
Estimate |
Standard Error |
t Value |
Pr > |t| |
95% Confidence Interval |
| Mean Ground Count |
27.28108 |
0.815041 |
33.47 |
<.0001 |
25.43733 |
29.12483 |
| Total Ground Count |
5456.21622 |
163.008165 |
33.47 |
<.0001 |
5087.46613 |
5824.96630 |
| NOTE: |
The denominator degrees of freedom for the t tests is 9. |
|